rem                            C_PtC.cdl
rem        Copy Right by International Technology Transfer Corp.
rem        revision 1.0-7/30/99   


rem        ********************************************************************
rem        Circle tangent to circle with the specified radius through the point
rem        1. Select Circle
rem        2. Select Point to go through
rem        3. Enter radius
rem        4. Draw Circle
rem        ********************************************************************

clear
defopt = 2
r1 = 1.0
array mtx[9]
acc = 0.00001

:start
	flag = 0

	getent "Select Circle",enttype
	on (@key + 3) goto exit, start,
	if (enttype!=3)
		goto start
	vnum = @intdat[8]
	vx0 = @fltdat[0]
	vy0 = @fltdat[1]
	vz0 = @fltdat[2]
	r0 = @fltdat[3]

	getview vnum, mtx

:pos
	getpos "Indicate Point",defopt
	on (@key + 3) goto exit, start, pos, 
	defopt=@key
	x1 = @xworld
	y1 = @yworld
	z1 = @zworld

rem
	call xfmwv, mtx, x1, y1, z1, vx1, vy1, vz1

	if (abs(vz0-vz1)<acc)
		goto check1
	pause "Point and Circle are not on the same plane"
	goto start

:check1
	dist = sqrt( (vx0 - vx1) * (vx0 - vx1) + (vy0 - vy1) * (vy0 - vy1) )

	if (dist<acc)
		goto start

:getrad
	getflt "Enter Radius", r1, r1

	on (@key + 3) goto exit, pos, , 
	
	view vnum, mtx[0], mtx[1], mtx[2], mtx[3], mtx[4], mtx[5], mtx[6], mtx[7], mtx[8]
	if (r0 > dist)
		goto case1
	if (r0 < dist)
		goto case2
	
rem     ************  If the point is inside the circle  ************
:case1
	if (r1-(r0-dist)/2<-acc)
		goto case1_1
	if (r1-(r0-dist)/2<acc)
		goto case1_2
	if (r1-(r0+dist)/2<-acc)
		goto case1_3
	if (r1-(r0+dist)/2<acc)
		goto case1_4
	goto case1_1
	
:case1_1
	pause "Radius is not correct!"
	redraw
	goto exit

rem     One circle(Smaller one)
:case1_2
	x1 = ( (dist-r0)/2*vx0 + (dist+r0)/2*vx1 )/dist
	y1 = ( (dist-r0)/2*vy0 + (dist+r0)/2*vy1 )/dist
	circle x1, y1, vz0, r1, vnum
	redraw
	goto exit

rem     Two circles
:case1_3

	dx = vx0 - vx1
	dy = vy0 - vy1
	a = dx*dx + dy*dy - r0*r0 + 2*r0*r1
	b = sqrt( 4*r1*r1*(dx*dx + dy*dy) - a*a )
	c = 2 * (dx*dx + dy*dy)
	x1 = vx1 + ( dx*a + dy*b ) / c
	y1 = vy1 + ( dy*a - dx*b ) / c
	x2 = vx1 + ( dx*a - dy*b ) / c
	y2 = vy1 + ( dy*a + dx*b ) / c

	circle x1, y1, vz0, r1, vnum
	circle x2, y2, vz0, r1, vnum
	redraw
	goto exit

rem     One circle (Larger circle)
:case1_4
	x1 = ( (dist+r0)/2*vx0 + (dist-r0)/2*vx1 )/dist
	y1 = ( (dist+r0)/2*vy0 + (dist-r0)/2*vy1 )/dist
	circle x1, y1, vz0, r1, vnum
	redraw
	goto exit

rem     ************  If point is outside the circle  ************
:case2
	if (r1-(dist-r0)/2<-acc)
		goto case2_1
	if (r1-(dist-r0)/2<acc)
		goto case2_2
	if (r1-(dist+r0)/2<-acc)
		goto case2_3
	if (r1-(dist+r0)/2<acc)
		goto case2_4
	goto case2_5
	
:case2_1
	pause "The Number Is Not Correct"
	redraw
	goto start

rem     One Circle,
:case2_2
	x1 = ( r1*vx0 + (r0+r1)*vx1 ) / dist
	y1 = ( r1*vy0 + (r0+r1)*vy1 ) / dist
	circle x1, y1, vz0, r1, vnum
	redraw
	goto exit

rem     two circles,
:case2_3

	dx = vx0 - vx1
	dy = vy0 - vy1
	a = dx*dx + dy*dy - r0*r0 - 2*r0*r1
	b = sqrt( 4*r1*r1*(dx*dx + dy*dy) - a*a )
	c = 2 * (dx*dx + dy*dy)
	x1 = vx1 + ( dx*a + dy*b ) / c
	y1 = vy1 + ( dy*a - dx*b ) / c
	x2 = vx1 + ( dx*a - dy*b ) / c
	y2 = vy1 + ( dy*a + dx*b ) / c

	circle x1, y1, vz0, r1, vnum
	circle x2, y2, vz0, r1, vnum
	redraw
	goto exit

rem     three circles
:case2_4

	dx = vx0 - vx1
	dy = vy0 - vy1
	a = dx*dx + dy*dy - r0*r0 - 2*r0*r1
	b = sqrt( 4*r1*r1*(dx*dx + dy*dy) - a*a )
	c = 2 * (dx*dx + dy*dy)
	x1 = vx1 + ( dx*a + dy*b ) / c
	y1 = vy1 + ( dy*a - dx*b ) / c
	x2 = vx1 + ( dx*a - dy*b ) / c
	y2 = vy1 + ( dy*a + dx*b ) / c

	x3 = ( r1*vx0 + (r1 - r0)*vx1 ) / dist
	y3 = ( r1*vy0 + (r1 - r0)*vy1 ) / dist

	circle x1, y1, vz0, r1, vnum
	circle x2, y2, vz0, r1, vnum
	circle x3, y3, vz0, r1, vnum
	redraw
	goto exit

rem     4 circles
:case2_5

	dx = vx0 - vx1
	dy = vy0 - vy1
	a = dx*dx + dy*dy - r0*r0 - 2*r0*r1
	b = sqrt( 4*r1*r1*(dx*dx + dy*dy) - a*a )
	c = 2 * (dx*dx + dy*dy)
	x1 = vx1 + ( dx*a + dy*b ) / c
	y1 = vy1 + ( dy*a - dx*b ) / c
	x2 = vx1 + ( dx*a - dy*b ) / c
	y2 = vy1 + ( dy*a + dx*b ) / c


	dx = vx0 - vx1
	dy = vy0 - vy1
	a = dx*dx + dy*dy - r0*r0 + 2*r0*r1
	b = sqrt( 4*r1*r1*(dx*dx + dy*dy) - a*a )
	c = 2 * (dx*dx + dy*dy)
	x3 = vx1 + ( dx*a + dy*b ) / c
	y3 = vy1 + ( dy*a - dx*b ) / c
	x4 = vx1 + ( dx*a - dy*b ) / c
	y4 = vy1 + ( dy*a + dx*b ) / c

	circle x1, y1, vz0, r1, vnum
	circle x2, y2, vz0, r1, vnum
	circle x3, y3, vz0, r1, vnum
	circle x4, y4, vz0, r1, vnum
	redraw
	

:exit
	clear