rem                            D_2Ln.cdl
rem        Copy Right by International Technology Transfer Corp.
rem        revision 1.0-7/30/99   



rem        ********************************************************************
rem        Distance between two lines
rem        1. select 1st line
rem        2. select 2nd line
rem        3. Calculate distance
rem        ********************************************************************

clear
acc = 0.0001

:start
	getent "Select First Line",enttype
	on (@key + 3) goto exit,start,start,
	if (enttype!=2)
		goto start
	x1 = @fltdat[0]
	y1 = @fltdat[1]
	z1 = @fltdat[2]
	x2 = @fltdat[3]
	y2 = @fltdat[4]
	z2 = @fltdat[5]
	
	f1 = x2 - x1
	g1 = y2 - y1
	h1 = z2 - z1
	
	
:second
	getent "Select Second Line",enttype
	on (@key + 3) goto exit, start, second, 
	if (enttype!=2)
		goto second
	
	x3 = @fltdat[0]
	y3 = @fltdat[1]
	z3 = @fltdat[2]
	x4 = @fltdat[3]
	y4 = @fltdat[4]
	z4 = @fltdat[5]
	
	f2 = x4 - x3
	g2 = y4 - y3
	h2 = z4 - z3

rem     ***********************************************************************
rem     Dist = abs(bunshi) / bunbo
rem
rem              | x3 - x1    y3 - y1   z3 - z1 |
rem     bunshi = |    f1         g1        h1   |
rem              |    f2         g2        h2   |
rem
rem     bunbo = sqrt(fg*fg + gh*gh + hf*hf)
rem
rem     fg = f1*g2 - f2*g1 , gh = g1*h2 - g2*h1 , hf = h1*f2 - h2*f1
rem     ***********************************************************************
	fg = f1 * g2 - f2 * g1
	gh = g1 * h2 - g2 * h1
	hf = h1 * f2 - h2 * f1

	bunbo = fg * fg + gh * gh + hf * hf
rem     If pararel, f1:f2 = g1:g2 = h1:h2 and bunbo becomes 0
	if (bunbo<acc)
		goto parallel
	
		
	dist = abs((x3-x1)*gh + (y3-y1)*hf + (z3-z1)*fg)
	dist=dist / sqrt(bunbo)

rem     ************************************************
rem     Line perpendicular to two lines
rem     x5=x1+f1*s, y5=y1+g1*s, z5=z1+h1*s (s is parameter)
rem     x6=x3+f2*t, y6=y3+g2*t, z6=z3+h2*t (t is parameter)
rem     f3=x6-x5, g3=y6-y5, h3=z6-z5
rem     
rem     f1*f3+g1*g3+h1*h3=0, f2*f3+g2*g3+h2*h3=0  ‚Æ‚È‚é
rem     f1*(x3-x1+f2*t-f1*s)+g1*(y3-y1+g2*t-g1*s)+h1*(z3-z1+h2*t-g1*s)=0
rem     f2*(x3-x1+f2*t-f1*s)+g2*(y3-y1+g2*t-g1*s)+h2*(z3-z1+h2*t-g1*s)=0

rem     -(f1*f1+g1*g1+h1*h1)*s+(f1*f2+g1*g2+h1*h2)*t+f1*(x3-x1)+g1*(y3-y1)+h1*(z3-z1)=0
rem     -(f2*f1+g2*g1+h2*h1)*s+(f2*f2+g2*g2+h2*h2)*t+f2*(x3-x1)+g2*(y3-y1)+h2*(z3-z1)=0
rem     Solve above equation for s and t
rem     *************************************************

	a1 = -(f1 * f1 + g1 * g1 + h1 * h1)
	a2 = -(f1 * f2 + g1 * g2 + h1 * h2)
	b1 = f1 * f2 + g1 * g2 + h1 * h2
	b2 = f2 * f2 + g2 * g2 + h2 * h2
	c1 = f1 * (x3-x1) + g1 * (y3-y1) + h1 * (z3-z1)
	c2 = f2 * (x3-x1) + g2 * (y3-y1) + h2 * (z3-z1)
	
	s = ( -b1 * c2 + c1 * b2) / bunbo
	t = ( a1 * c2 - c1 * a2) / bunbo

	x5 = x1 + f1 * s
	y5 = y1 + g1 * s
	z5 = z1 + h1 * s
	x6 = x3 + f2 * t
	y6 = y3 + g2 * t
	z6 = z3 + h2 * t

rem     
	mode draw
	line x5, y5, z5, x6, y6, z6, 15, ,2
	mode normal

	pause " Distance between two Lines = %.3f", dist
	redraw
	goto exit

:parallel

rem     ***********************************************************************
rem     if two lines are parallel
rem     ***********************************************************************
	t = (f2 * (x1-x3) + g2 * (y1-y3) + h2 * (z1-z3)) / (f2*f2 + g2*g2 + h2*h2)

	x5 = x3 + f2 * t
	y5 = y3 + g2 * t
	z5 = z3 + h2 * t

	mode draw
	line x1, y1, z1, x5, y5, z5, 15, ,2
	mode normal

	dist=sqrt((x1-x5)*(x1-x5)+(y1-y5)*(y1-y5)+(z1-z5)*(z1-z5))
	pause " Distance between Two Lines = %.3f", dist
	redraw
	
:exit